0 BEGIN PGM vriden kant Huron MM
1 ;Fräser kanten med variabel slappning
2 ;KINEMATIC ...Huron ab 45 graders huvud
3 ;Programmet visar korrekt grafik, VPI febr 2010...
4 BLK FORM 0.1 Z X-210 Y-210 Z-80
5 BLK FORM 0.2 X+210 Y+210 Z+0
6 TOOL CALL 40 Z S1000
7 L Z+100 R0 FMAX
8 L A+0 C+0 R0 FMAX
9 L X-150 Y-240 Z+10 R0 FMAX M3
10 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR
11 L A+0 B+0 F10000
12 L Z-75 R0 F1000
13 L X-150 Y-240 R0
14 L IX+150 IA-45
15 L IX+150 IA+45
16 L Z+50 R0 FMAX
17 FUNCTION RESET TCPM
18 L A+0 C+0 R0 FMAX M2
19 END PGM vriden kant Huron MM
 

Maskinen har 45 graders Huronhuvud AC, steglöst F i AC.

Med TCPM....AXIS SPAT... kan man programmera A som rymdvinkel, dvs verktyget ska luta A grader kring X-axeln (oberoende av om maskinens A finns - den kan vara en annan vinkel, t ex B).

Block 14-15 gör ytan, se bilden.

Valter Isander den 23 febr 2010

I programmet pendlar A-axeln  - + 45°.
I maskinen utförs detta av A och C.

0 BEGIN PGM kon 5 axl TCPM SPAT MM
1 ;Fräser kon 5 axl BC swivell table... med TCPM...SPAT
2 ;Programmet visar korrekt grafik, VPI febr 2010...
3 BLK FORM 0.1 Z X-100 Y-100 Z-100
4 BLK FORM 0.2 X+100 Y+100 Z+0
5 TOOL CALL 20 Z S1000
6 L Z+100 R0 FMAX
7 L X-100 Y+0 Z+10 R0 FMAX M3
8 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR ;obs SPAT så funkar rymdvinkel AB, även för Huron huvuden
9 L A+0 B+0 C+0 F10000 ;inget M128 haer
10 L Z-75 B+20 R0 F1000

17 Q1 = 180 ;grad
18 LBL 1
19 Q1 = Q1 - 3 ;grad
20 Q2 = 100 * COS Q1 ;x
21 Q3 = 100 * SIN Q1    ;y
22 L X+Q2 Y+Q3 IC-3   ;C är spatial vinkel nu
23 CALL LBL 1 REP119
24 L Z+50 R0 FMAX
25 L A+0 B+0 C+0 R0 FMAX
26 FUNCTION RESET TCPM
27 M2
28 END PGM kon 5 axl TCPM SPAT MM
 

TCPM  AXIS SPAT...

Jag kör konan helt varv med vanlig pinnfräs.

block 17-23, XY beräknas i cirkeln med Q. Se kommentar i ex 1 ovan för noggrann kona.

Testat i grafik i olika maskiner:

- vagga A, bord C, typ Hermle

- bord BC, det ena 45 grader

- Huronhuvud 45 grader. 

Valter Isander, Rönninge

Axlarna i en Hermle eller motsvarande

Maskinen har roterande bord C, alltså går det bra med den enklare M128 för att styra verktygsspetsen (jfrt med TCPM).

Observera att Med M128 och "de andra" 3D-funktionerna (PLANE, TCPM, CYCL 19) måste man inte sätta konens mitt i C-bordets mitt!

Jacket i bottenytan är block 8.
Block 11 bör nog köras med mindre inkrement.

Valter 24 febr 2010

3 axlar XYZ och huvud B och bord C.

Titta på bearbetningen som film på Youtube! (den bearbetningen körs dock med 90° nedvriden, horisontell spindel (PLANE). Själva körningen 5-axligt sker med TCPM ("M128").
   

I block 11 ställer jag in A-25 grader.

Tack vare TNC:s TCPM, block 10, kan man programmera verktygets RYMDvinkel ABC i förhållande till XYZ (A,B,C resp) oavsett vad maskinens axlar heter (i detta fall AC fysiska axlar).

Enkel programmering? Javisst. Men obs - använd TCPM ...AXIS SPAT(ial)...ej AXIS POS.

I detta fall funkar det med CP...IC+90... men man kan vara tvungen att stycka upp CP i många L-block.

 Valter den 24 febr 2010

Maskinens axlar AC.

Observera att detaljens nolla och vridnings-punkten CC i hörnen INTE behöver ligga i bordets rotationscentrum (som man måste på gamla manuella maskiner vad jag förstår).

1 Flytta nollan X50, ty där vill jag ha vridningspunkten i PLANE

2 Vrid koord.systemet kring Y  dvs B+30 i PLANE SPATIAL...SPB+30...

3 Plana i XYZ som vanligt, dvs Z är den sneda verktygsaxeln)

4 Byt verktyg till borr, verktygsaxel är Z som vanligt - det är DET som är grunden i allt detta med vridningar i TNC!

5 Samma PLANE igen

6 Borra 2 hål med M99 som vanligt

7 Kör bort, reset, M2

Block 20 PLANE SPATIAL...SPB+30... vrider denna maskins axlar A och C så att verktyget lutar 30 grader i förhållande till koordinat-systemet (dvs kring Y i detta fall).

Den beräkning som behövs för detta ligger inne i TNC:s software för PLANE (samma som för CYCL 19, om man har ställt in systemet så att vinkeln betyder "rymdvinkel", ej fysisk maskinvinkel).

Bilden visar den inledande planfräsningen. Det gröna XYZ-systemet är vrids av PLANE i block 13, så att Z ligger längs verktygets axelriktning.

/Valter Isander 25 februari 2010

0 BEGIN PGM Borra i kub 2 sidor med CYCL19 MM
1 BLK FORM 0.1 Z X-100 Y-200 Z-100
2 BLK FORM 0.2 X+100 Y+0 Z+100
3 TOOL CALL 15 Z S1000 ;borr
4 L Z+300 R0 FMAX
5 CYCL DEF 200 BORRNING ~
Q200=+2 ;SAEKERHETSAVSTAAND ~
Q201=-90 ;DJUP ~
Q206=+500 ;MATNING DJUP ~
Q202=+30 ;SKAERDJUP ~
Q210=+0 ;VAENTETID UPPE ~
Q203=+100 ;KOORD. OEVERYTA ~
Q204=+50 ;2. SAEKERHETSAVST. ~
Q211=+0 ;VAENTETID NERE
6 CYCL DEF 19.0 BEARBETNINGSPLAN
7 CYCL DEF 19.1 B+0
8 L X+0 Y-100 B+0 R0 FMAX M3 M99
9 L Z+300 R0 FMAX
10 CYCL DEF 19.0 BEARBETNINGSPLAN
11 CYCL DEF 19.1 B+90
12 L B+90 R0 FMAX
13 L X+0 Y-100 R0 FMAX M3 M99
14 L Z+200 R0 FMAX
15 CYCL DEF 19.0 BEARBETNINGSPLAN
16 CYCL DEF 19.1 B+0
17 CYCL DEF 19.0 BEARBETNINGSPLAN
18 CYCL DEF 19.1
19 L X+0 Y+0 B+0 R0 FMAX M2
20 END PGM Borra i kub 2 sidor med CYCL19 MM
 

3+2-axl:
PGM6
Vrida biten

Förr i tiden:

När man vred på biten satt ju nollan kvar i luften i första läget, dvs man måste göra en nollpunktsförflyttning, eller mäta in nollan igen på nya ytan. Eller så satte man biten och nollan exakt i mitten av bordet jobbigt...

Numera:

Med TNC CYCL 19 eller PLANE så vrider man biten (B-axeln) och nollan N sitter kvar PÅ BITEN, dvs följer med biten.

Man slipper alltså nolla om på biten.

Prova! Men ta g det försiktigt - din maskin beter sig kanske inte som detta exempel...

Valter

I bilden till vänster är grafikbilden vriden uppåt. X är egentligen horisontell i denna maskin.

En vanlig horisontell flerop med B-bord.
Z är horisontell.

Detaljen visas i första läget B0. I nästa läge B+90 sitter den till höger om B-centrum. XYZ-nollan följer med på biten (CYCL 19 eller PLANE).

0 BEGIN PGM Backe R50 45 grd TCPM MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-37
2 BLK FORM 0.2 X+100 Y+120 Z+0
3 TOOL CALL 17 Z S1000 ;Fullradie 20
4 L Z+100 X+0 Y+0 A+0 C+0 R0 FMAX
5 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR   ;M128 FOER 45 GRADERS HURON...
6 L Z+100 X+0 Y+0 A+0 C+0 R0 FMAX
7 L X+40 Y+0 R0 FMAX M3
8 L Z+0 R0 F500
9 ;
10 Q10 = 50 ;DETALJ R
11 Q1 = 0 ;GRADER
12 CALL LBL 1 ;en baage ner
13 ;
14 Q11 = Q108 * 1.5 ;SKAERBREDD
15 LBL 10
16 L IY+Q11
17 Q1 = 45 ;GRADER
18 CALL LBL 2
19 L IY+Q11
20 Q1 = 0 ;GRADER
21 CALL LBL 1
22 CALL LBL 10 REP 2 ;sidled
23 L Z+100 R0 FMAX
24 FUNCTION RESET TCPM
25 L A+0 C+0 R0 FMAX
26 M2
27 ;
28 LBL 1 ;baage ner
29 Q1 = Q1 + 1 ;VINKEL B
30 Q2 = 40 + Q10 * SIN Q1 ;X
31 Q3 = - Q10 + Q10 * COS Q1 ;Z
32 L X+Q2 Z+Q3 B+Q1
33 CALL LBL 1 REP44
34 LBL 0
35 ;
36 LBL 2 ;baage upp
37 Q1 = Q1 - 1 ;VINKEL B
38 Q2 = 40 + Q10 * SIN Q1 ;X
39 Q3 = - Q10 + Q10 * COS Q1 ;Z
40 L X+Q2 Z+Q3 B+Q1
41 CALL LBL 2 REP44
42 LBL 0
43 ;
44 END PGM Backe R50 45 grd TCPM MM

3D-vy i mode PROGRAM INMATNING

Alla 5:
PGM7
3-axlig R50
"planfräsning"

Med TCPM ...AXIS SPAT...    följer pinnfräsens ände den programmerade punkten, och verktygets vinkel står hela tiden vinkelrätt mot radieytan, se bild.

Kärnan i detta program är (förutom TCPM) LBL 1 (kör nedför bågen), och LBL 2 (uppför).

CP i st för beräknade punkter (LBL 1+2) funkade inte för mig i denna maskin, alltså styckar jag upp bågen R50 i många korta Linjära (block 32 och 40). Man kanske bör göra stegen Q1 (block 29/37) ännu mindre, annars blir ytan facetterad.

Man kan fundera på om man kan köra med "fronten" av fräsen i st f centrum - det kan ge bättre avverkning, och man måste inte ha en fräs som skär i centrum.

Maskinen har ett "Huronhuvud 45 graders, fullt styrt förstås.

Många maskiners huvuden har dock stegvist inställbara vinklar, t ex 1° eller 2,5° steg. Då funkar naturligtvis inte detta  program. Lösningen får då bli en stegning XYZ, kanske med en radiefräs. Men DET är ett annat kapitel, visas ej på denna sida.

/ Valter den 27 februari 2010.

Alla 5: Pgm 8
SPÅR inne i en cylinderyta,
med vanlig pinnfräs.

Block 28 + 29 fräser ett spår.

Med hjälp av TCPM...AXIS SPAT... står pinnfräsen vinkelrätt (som en cirkelradie) mot spårbotten. Man slipper alltså ta in en T-spårsfräs, i stället kör man med vanliga pinnfräsen för raka spår. Och man slipper förstås ursvarva spåret... eller ännu värre - svarva...

Jag var tvungen att använda två CP-block efter varandra, jag vet ej varför det inte går med ett CP hela varvet.

Om man får problem med cirkulär rörelse bör man prova att generera cirkeln med Q och L i små steg. LP funkar dåligt eftersom LP tyvärr inte kan innehålla A, B eller C-ord.

Man kan förstås fräsa alla möjliga cirkulära hack i biten, prova att leka! Men jag har inte kört programmet i en maskin, bara i grafik/ maskingrafik.

Valter Isander
Rönninge 27 februari 2010

Maskinen (XYZ AC) mitt i block 29 (ej 30..) CP... som fräser spåret med pinnfräsen.

Spindelhuvudet måste naturligtvis få rum inne i håligheten, i detta fall D400 mm.

3+2-axl:
PGM9
Borra snett på ovansidan!

Nu ska vi borra fyra hål snett på toppen av en plan yta!

Snedställningen får man som vanligt med PLANE SPATIAL A0 B+30 C+45..., då ligger Z längs hålet.

Men man måste vrida i hålets mynning i detta fall, eftersom måtten på biten går på plana ytan (delningen X20). Alltså sätter man FÖRST nollan i hålet, SEDAN vrider man. Ty ALL vridning i TNC 3D sker kring gällande nollpunkt! Basic kunskap!

Nästa hål samma tänk: Alltså... flytta nollan till nästa hål, vrid sedan. DÅ måste du tänka på att nollpunktsförflyttningar ALLTID sker i aktuellt (ev. vridet) plan. Alltså... tag bort PLANE före NOLLP IX+20, aktivera sedan PLANE igen (bl 24-29).

För att slippa en massa fysiska vridningar varje hål så kör du med PLANE...STAY (då står maskinen stilla, men koordinatsystemet vrids internt). Kul va!

På ritningen är hålet vridet:
B+30° (kring Y) sedan C+45 (kring vertikala Z).

Allmänt gäller:

A= vrida kring X
B=vrida kring Y
C=vrida kring Z

Observera att ABC är rymdvinklar! Dvs det är verktygets vinkel i XYZ-systemet. MASKINENS vinkelaxlar kan vara vad som helst, i detta fall kallas de A och C, trots att A egentligen vrids på nåt skumt sätt kring en 45-gradersaxel (Huronhuvud). Men allt det där fixar TNC med CYCL 19 eller PLANE.

Efter PLANE (block 29) kan du kolla vad vinklarna på maskinens A, C (nacke och huvud) fick för värden:
A=Q120
B=Q121  (i denna maskin finns ingen B, alltså B=0 i listan).
C=Q122

Q-listan ser genom att trycka på Q-knappen. Du kan se värdena även i PROGRAMTEST.

Du måste naturligtvis ha valt en maskin i datorn som ser ut som din maskin i verkstaden: MOD + KOD=KINEMATIC + välj en maskin.

0 BEGIN PGM KERNTEST MM
1 ; SKAPAD 05-29-1998 KL 18:24:17 UR FILEN KERNTEST.CLS MED PROGRAMVARA~
TNC3DK.EXE 1.0
2 BLK FORM 0.1 Z X-2 Y-7 Z-3
3 BLK FORM 0.2 X+7 Y+7 Z+5
4 TOOL CALL 2 Z S20000 DL+0 DR+1 DR2:+1
5 L M3
6 * - TOOL PATH 1
7 L F600 M107
8 LN X+6 Y-7 Z+2 NX+0 NY-0.7 NZ+0.7141428
9 L F50
10 LN X+6 Y-7 Z-2.8586 NX+0 NY-0.7 NZ+0.7141428
11 L F300
12 LN X+6 Y-5.8129 Z-1.8631 NX+0 NY-0.5812939 NZ+0.8136936
13 LN X+6 Y-4.4864 Z-1.0629 NX+0 NY-0.448636 NZ+0.8937146
14 LN X+6 Y-3.0521 Z-0.4771 NX+0 NY-0.3052101 NZ+0.9522851
15 LN X+6 Y-1.5446 Z-0.12 NX+0 NY-0.1544586 NZ+0.9879993
16 LN X+6 Y+0 Z+0 NX+0 NY+0 NZ+1
17 LN X+6 Y+1.5446 Z-0.12 NX+0 NY+0.1544586 NZ+0.9879993
18 LN X+6 Y+3.0521 Z-0.4771 NX+0 NY+0.3052101 NZ+0.9522851
19 LN X+6 Y+4.4864 Z-1.0629 NX+0 NY+0.448636 NZ+0.8937146
20 LN X+6 Y+5.8129 Z-1.8631 NX+0 NY+0.5812939 NZ+0.8136936
21 LN X+6 Y+7 Z-2.8586 NX+0 NY+0.7 NZ+0.7141428
22 LN X+4.6053 Y+7 Z-2.8586 NX+0 NY+0.7 NZ+0.7141428
23 LN X+4.6053 Y+5.8129 Z-1.8631 NX+0 NY+0.5812939 NZ+0.8136936

Del av NC-program för ett verktyg för att pressa skärplattor före sintringen.

3-axl:
PGM10 
3D-yta
med 3D-verktygsradie-kompensering i TNC

Vad är nu detta??

Jo! I CAD-CAM kan man ju mata ut ett TNC-program för en 3D-yta med en massa täta LN-block.

Varje LN (en linjär rörelse) har dels X..Y..Z..= en skärpunkt på ytan, dels NX NY NZ som är "pilar" som tillsammans bildar "normalen", normalvektorn N, till ytan i punkten XYZ.

Normalvektorn pekar förstås rätt in i verktygets (t ex en fullradiefräs) centrum.

Man kan i TNC enkelt lägga på/dra bort - "luras" på verktygsradien i TOOL CALL.... DR... DR2:... (DR.. är stammen, DR2.. är hörnradien på fräsen)

T ex om man sätter DR+1 DR2:+1  så lämnar verktyget 1 mm material över hela ytan, man kör ett grovskär.

Man kan också enkelt byta till annan verktygsdimension (verktygstabellens DR...DR2:...).

Förr i tiden måste man köra om CAD-CAM med olika verktygsradier, det blev en massa hemskt långa program att hantera. Nu har man ETT program, kanske två, kan snabbt justera avverkningen i TOOL CALL-blocket! Och skifta mellan olika verktyg för samma yta.

Men man måste ha en postprocessor som matar ut normalvektorer till TNC. Det är en baggis för ett vanligt CAD-CAM med 3D.

En vanlig 3-axlig maskin XYZ

I detta program svänger ytan i bara YZ, dvs normalvektorns NX-komponent är noll (se programmet till vänster)

0 BEGIN PGM Kon 15 grader som lutar 20 grader  MM
1 ;Fraser kon 5 axl AB head... med PLANE och TCPM...SPAT
2 ;
3 BLK FORM 0.1 Z X-90 Y-110 Z-140
4 BLK FORM 0.2 X+90 Y+75 Z+0
5 PLANE SPATIAL SPA-20 SPB+0 SPC+0 MOVE DIST0 FMAX
6 TOOL CALL 20 Z S1000
7 L Z+100 R0 FMAX
8 L X-170 Y+0 Z+50 R0 FMAX M3
9 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR ;obs SPAT så funkar rymdvinkel AB, även för Huron huvuden
10 L A+0 B+0 C+0 F10000
11 L Z-75 B+15 A+0 C+0 R0 F1000
12 CC X+0 Y+0
13 Q1 = 180 ;grad
14 LBL 1
15 Q1 = Q1 - 1 ;grad
16 Q2 = 100 * COS Q1 ;x
17 Q3 = 100 * SIN Q1 ;y
18 L X+Q2 Y+Q3 IC-1 ;C är spatial vinkel nu
19 CALL LBL 1 REP359
20 L IX-10
21 M140 MB+100 F1000        ;backa ifrån längs verktyget

22 L Z+50 R0 FMAX
23 L A+0 B+0 C+0 R0 FMAX
24 FUNCTION RESET TCPM
25 PLANE RESET
26 M2
27 END PGM .....M

Alla 5:
PGM11

Kona som lutar 20°!

Detta är kul!

• Konens axel lutar 15° (block 11).
   

• Hela rasket lutar 20° (block 5)
   

• Kört i en maskin som inte kan vränga spindeln negativt (kan inte peka in i magen på maskinen).
  
  Alltså lägger jag upp biten på en sned hylla (20°), och vrider även koord.systemet med PLANE lika mycket (block 5). Då kör jag inte maskens huvud i gränsläge...

Man kunde nog ha satt biten på vertikal hylla, men nu håller vi på i sandlådan och testar...

Maskin med XYZ AB (kontinuerligt matningsbara axlar samtidigt).

På YouTube
 

Här har jag planat: först toppen med CYCL 232 PLANA, och i slutet botten med CYCL 257 CIRKULÄR Ö. Lite trixigt att hitta Z-djupet i botten, eftersom fräsen körde konen vinklat 15°, och då åkte verktygets CENTRUM på Z-75 (block 11). Exakt bör djupet bli Z-75 - verkt.R x cos 15° ( konvinkeln! inte lutande planet som ju är 20°).

0 BEGIN PGM Kon 5 axl skapa NC-fil ur pos MM
1 ;
2 ;
3 BLK FORM 0.1 Z X-90 Y-110 Z-140
4 BLK FORM 0.2 X+90 Y+75 Z+0
5 PLANE SPATIAL SPA-20 SPB+0 SPC+0 MOVE DIST0 FMAX
6 TOOL CALL 20 Z S1000
7 ;
8 L Z+100 R0 FMAX
9 L X-170 Y+0 Z+50 R0 FMAX M3
10 FUNCTION TCPM F CONT AXIS SPAT PATHCTRL VECTOR ;obs SPAT så funkar rymdvinkel AB, även för Huron huvuden
11 L A+0 B+0 C+0 F10000
12 L Z-75 B+15 A+0 C+0 R0 F1000
13 CC X+0 Y+0
14 Q1 = 180 ;grad
15 LBL 1
16 Q1 = Q1 - 4 ;grad
17 Q2 = 100 * COS Q1 ;x
18 Q3 = 100 * SIN Q1 ;y
19 L X+Q2 Y+Q3 IC-4 ;C är spatial vinkel nu     Detta är det egentlige bearbetningsblocket

20 ;Läs maskinens REF pos nu!
21 FN 18: SYSREAD Q11 = ID240 NR1 IDX1 ;laes REF X
22 FN 18: SYSREAD Q12 = ID240 NR1 IDX2 ;laes REF Y
23 FN 18: SYSREAD Q13 = ID240 NR1 IDX3 ;laes REF Z
24 FN 18: SYSREAD Q14 = ID240 NR1 IDX4 ;laes REF A
25 FN 18: SYSREAD Q15 = ID240 NR1 IDX5 ;laes REF B

26 FN 16: F-PRINT KONxyzab.a / KonXYZAB-REF.A                ;se formatfilen KONxyzab.A nedan (en rad bara)
27 ;
28 CALL LBL 1 REP90
29 L IX-10
30 M140 MB+100 F1000
31 L Z+50 R0 FMAX
32 L A+0 B+0 C+0 R0 FMAX
33 FUNCTION RESET TCPM
34 M2
35 END PGM Kon 5 axl skapa NC-fil ur pos MM
 

Förklaring:

1 Först läser jag (bl 21-25) REF-pos i maskinen...XQ11....BQ15
2 Sedan skriver jag dessa värden i en rad i filen  KonXYZAB-REF.A (listan till höger)
3 enligt formatfilen i block 26 ovan:   KONxyzab.a
4 formatfilens rad (filen KONxyzab.A) är i detta fall:
"L X%9.4LF Y%9.4LF Z%9.4LF A%9.4LF B%9.4LF",Q11,Q12,Q13,Q14,Q15;

vilket ger utmatningen till höger (fr o m block 8 till 98).

Alla 5:
PGM12:
Konisk program-generator
(samma bit som pgm 10 ovan)

Varför har jag gjort detta program (till vänster)?

Jo, jag använder en TNC530 med PLANE..TCPM för att generera ett program för en maskin UTAN PLANE...TCPM (dock ska den ha M114 eller M128 om man kör roterande axlar).

Om du har en gammal TNC530 kan du leka med dessa möjligheter, kluriga, men jag tror på principen...

Idén är att man simulerar programmet till vänster, t ex i en PC, låter det skapa XYZAB ur REF-koordinaterna i maskinen som ett nytt program (till höger). Sedan kör jag det nya programmet.

Det ser åtminstone riktigt ut på grafiken! MED M128, annars tappar troligen TNC bort verktygsspetsen.

Principen kan förstås användas för att i simuleringen borra sneda hål med CYCL 19/PLANE, och samtidigt "sno" koordinaterna, sedan köra dem i en urgammal maskin med vridbart huvud. T ex en gammal TNC355.

Är du med?!

Valter Isander
den 1 mars 2010
Rönninge

0 BEGIN PGM C27 MM
1 ;B head och C table
2 BLK FORM 0.1 Z X+200 Y-100 Z-100
3 BLK FORM 0.2 X+300 Y+100 Z+100
4 TOOL CALL 1 Z S2000 ; Diameter 7
5 L Z+250 R0 FMAX
6 L X+300 Y+0 R0 FMAX
7 L C+0 R0 FMAX
8 PLANE SPATIAL SPA+0 SPB+90 SPC+0 MOVE DIST0 FMAX ;Positioning
9 CYCL DEF 14.0 KONTUR
10 CYCL DEF 14.1 KONTURLABEL1

11 CYCL DEF 27 CYLINDERMANTEL ~
Q1=-7 ;FRAES DJUP ~
Q3=+0 ;TILLAEGG SIDA ~
Q6=+50 ;SAEKERHETSAVSTAAND ~
Q10=+7 ;SKAERDJUP ~
Q11=+100 ;MATNING DJUP ~
Q12=+250 ;MATNING FRAESNING ~
Q16=+240 ;RADIE ~
Q17=+1 ;MATTENHET

12 L Z+300 R0 FMAX
13 L C+0 X+0 Y+0 R0 FMAX M13
14 M99 ;Kör cykeln nu
15 L Z+300 R0 FMAX ;Retract the tool
16 PLANE RESET TURN FMAX ; Tilt back, cancel the PLANE function
17 L Z+150 R0 FMAX
18 L X+0 Y+0 R0 FMAX
19 M2
20 ;
21 LBL 1 ; Konturen, en invändig fyrkant i cylinderytan
22 L C+0 X+10 RL ; C betyder här mm (Q17=1 i CYCL DEF 27..)
23 L C+80
24 RND R7.5
25 L X+60
26 RND R7.5
27 L C-80
28 RND R7.5
29 L X+10
30 RND R7.5
31 L C+0
32 LBL 0
33 END PGM C27 MM
 

Alla 5:
PGM13:
CYCL 27
Cylindermantel

Med CYCL 27 m fl kan man i TNC programmera figurer på en cylinderyta, som om man programmerade dem på en plan yta!

Vitsen med cyklerna är att man slipper en massa Q-beräkningar, cyklerna fixar A-B-C-axlens vridning på aktuell radie där fräsen råkar jobba (räknat från rot.centrum). Man kan programmera L, CC+C, RND, RL/RR etc, dvs det blir enkelt att "rita" figurer, kurvor och annat snett i cylindrar.

Programmet till vänster fräser en enkel rektangel invändigt, måtten ser du i LBL 1.

Som du ser till vänster blir flankerna sneda... men välj en annan cykel (28,29,30) så kan du få som du vill där, dvs TNC gör då en liten förskjutning av verktyget utanför rot.axeln.

I detta exempel körde man först PLANE...B+90... så att Z blev vinkelrätt mot C:s rotationsaxel.

Kanske kan man även köra M128... det har jag inte provat, men då kan man kanske sätta cylindern OFF centrum... nä...?

Maskinen har C-bord, och B-huvud.
Klicka på bilden för större.

Här ser du fyrkanten med RND R7.5 i hörnen

3+2-axl:
PGM14:
Borra 1 hål i fyra sidor med PLANE!

Det här är en vanlig grej på verkstan, att borra i olika riktningar. Maskinen kan vrida huvudet (t ex med PLANE), så att Z+ pekar ut längs borrhålet som vanligt (jag borrar som vanligt hela tiden med Z).

Genom att flytta nollan (INNAN jag vrider med PLANE) till hålets yta, hörnet, så kan jag köra med samma borrcykel hela tiden (Q203=0).

Jag la själva borrningen i LBL 1, och passade på att gå upp i maskinens Z+ (med M91 alltså).

Samma arbetsstycke kan också borras med den äldre CYCL 19 Vrida koordinatsystem, se nästa programexempel nedan!

Nu borras hål nr 3

 
Maskinens normalläge.
Nacke är A, 45-graders huvud är B.

3+2-axl:
PGM15:
Borra 1 hål i fyra sidor med
CYCL 19!

Samma arbetsstycke och maskin som ovanstående exempel, men denna maskin har inte PLANE, men däremot den äldre CYCL 19, som har funnits i 10-15 år i TNC415B, 425, 426.430, iTNC530 m fl.

Tricket är att först begära vridning av koord.systemet med CYCL 19 (som i maskinparametrar i detta exempel är inställd på RYMDVINKEL, dvs inte huvudets fysiska vinklar!).

I CYCL 19 anger man samma vinklar som man skulle gjort i PLANE, t ex A-90 B+0 C+0 (dvs verktygets vinkel i förhållande till detaljens ursprungliga XYZ-system).

Detta vrider alltså XYZ-axlarna matematiskt, OCH beräknar aktuell maskins A- och B-vinklar så att rymdvinklarna blir rätt i maskinen! DETTA är "tricket". A, B och C för maskinen landar efter CYCL 19 i Q120, Q121 och Q122 respektive, och kan användas av programmeraren i dennes program för att vrida huvudet.

Alltså tar jag dessa Q och kör en vanlig linjär L för att vrida huvudet (block 29, 42, 53).

En del maskintillverkare totar ihop egna cykler för att vrida huvudet, och dessa cykler kan använda CYCL 19, eller PLANE internt, eller inte... och i senare fallet kan du nog ha nytta av Q120-122 som du stoppar in i den cykeln. Men kolla noga med din maskins manual och info...!

Maskiner med fasta lägen
i ABC

Du vet väl att många maskiner inte kan nå godtyckliga vinklar - de har en delning 1° eller 2,5°. Då ska du lära dig hur du kommer som närmast det som står på ritningen. Och kolla med kunden om det är okej att avvika si och så mycket från ritningen!

Valter Isander den 21 mars 2010

Samma maskin som exemplet ovan!

Maskinens normalläge.
Nacke är A, 45-graders huvud är B.

0 BEGIN PGM Slappning 3 sidor med PLANE MM
1 ;En liksidig trekant 100 mm sidor har slappning 15 grader pa tre sidor
2 ;Jag tar en maskin med B-huvud och C-bord, eftersom jag då kommer åt alla~
tre sidorna med vinkeln
3 ;Ett 45-graders huvud AB funkar inte på en av sidorna! Alltså väljer jag en maskin B-huvud, C-bord.
4 ;Triangelns bas är 100, toppen Y86.603
5 ;Valter Isander den 22 mars 2010
6 ;
7 BLK FORM 0.1 Z X-10 Y-10 Z-10
8 BLK FORM 0.2 X+110 Y+90 Z+20
9 TOOL CALL 25 Z S1000 ;Vanlig pinne
10 ;
11 PLANE RESET STAY
12 ;
13 ;Sida 1
14 CYCL DEF 7.0 NOLLPUNKT
15 CYCL DEF 7.1 X+100
16 CYCL DEF 7.2 Y+0
17 CYCL DEF 7.3 Z+0
18 L Z+100 R0 FMAX
19 PLANE SPATIAL SPA-15 SPB+0 SPC+0 MOVE FMAX
20 L X+55 Y+0 R0 FMAX M3
21 L X+55 Y+0 RL FMAX M3
22 L Z+0 RL F1500
23 L X-105 F550
24 L Z+100 R0 FMAX
25 PLANE RESET STAY ;reset eftersom jag vill flytta nollan. Stay eftersom det~
går snabbare
26 ;
27 ;Sida 2
28 Q20 = 50 * TAN 60 ;Y för triangelns övre spets
29 CYCL DEF 7.0 NOLLPUNKT
30 CYCL DEF 7.1 X+50
31 CYCL DEF 7.2 Y+Q20
32 CYCL DEF 7.3 Z+0
33 PLANE SPATIAL SPA+15 SPB+0 SPC-60 MOVE FMAX
34 L X-55 Y+0 R0 FMAX M3
35 L X-55 Y+0 RL FMAX
36 L Z+0 RL F1500
37 L X+105 F550
38 L Z+100 R0 FMAX
39 PLANE RESET STAY ;reset eftersom jag vill flytta nollan. Stay eftersom det~
går snabbare
40 ;
41 ;Sida 3
42 CYCL DEF 7.0 NOLLPUNKT
43 CYCL DEF 7.1 X+0
44 CYCL DEF 7.2 Y+0
45 CYCL DEF 7.3 Z+0
46 PLANE SPATIAL SPA+15 SPB+0 SPC+60 MOVE FMAX
47 L X-55 Y+0 R0 FMAX M3
48 L X-55 Y+0 RL FMAX M3
49 L Z+0 RL F1500
50 L X+105 F550
51 L Z+100 R0 FMAX
52 PLANE RESET MOVE DIST100 FMAX
53 M2
54 END PGM Slappning 3 sidor med PLANE MM
 

Fräsa tre kanter 15° med PLANE och RL

Sida 1 enkelt, bara luta verktyget 15° i block 19.
Jag flyttade nollan till högra hörnet först, men det var inte viktigt.

Sida 2: Nollan i övre spetsen, vrid A+15 och C-60, så att X+ går längs kanten.

Sida 3: Nollan i vänstra hörnet, vrid A+15, C+60, då löper X+ upp längs kanten (svarta axlar ritade av mig).

Verktyg valfritt, jag kör ju med RL som vanligt. Z lutar snett förstås.

Innan jag flyttar nollan stänger jag av med PLANE RESET.

B måste kunna vridas till 15 grader. C måste kunna vridas till multipler av 30 grader för denna triangel.

Anm: programmet är generellt för olika maskintyper, eftersom jag använder PLANE som fixar även 45-gradershuvuden etc. Men maskinen måste förstås mekaniskt kunna vinkla spindeln så att fräsen kommer åt överallt - ett vanligt huronhuvud fixar två av de tre sidorna (ej sida 1 på min triangel).

Valter testade den 22 mars 2010

När testar du och berättar hur det gick?!

valter.isander@telia.com

Maskin med B-huvud och C-bord

Just nu fräses 3:e sidan

Rätvinklig triangel, sidorna är 100 mm i basen,
sidorna lutar 15 grader

Titta på bearbetningen som film på Youtube! 
   

3+2-axl:
PGM16:

Fräsa tre kanter 15° med CYCL 19 och RL (i st f PLANE)

Samma tänk som föregående pgm 15, men nu med äldre CYCL 19 samt L BQ121  CQ122 i st för PLANE.

Maskinens parametrar ska vara inställda på RYMDVINKEL för CYCL 19, dvs A B C i CYCL 19 avser verktygets vinkel kring X Y Z-axlarna, inte maskinens fysiska axlar (i denna maskin B och C).

A-vinkeln i CYCL 19 är alltså ingen maskinvinkel - den finns ju inte, men CYCL 19 räknar ut lämpliga vinklar [Q120=maskinens A, Q121=B, Q122=C] för B och C i denna maskin (eller en annan maskintyps fysiska axlar ABC, definierade i maskinens maskinparametrar).

Valter Isander
den 23 mars 2010

0 BEGIN PGM M128 manuellt MM
1 BLK FORM 0.1 Z X-100 Y-100 Z-20
2 BLK FORM 0.2 X+100 Y+100 Z+0
3 TOOL CALL 1 Z S1000
4 L B+0 C+0 R0 FMAX ;B huvud. C bord steglöst
5 L X+75 Y+0 R0 FMAX M3
6 L Z+10 R0 FMAX
7 L Z-15 R0 F300 M128 F500         ;M128 gör att fräsen "följer med" hålet med C
8 L X+75 Y+0 C+90 R0 F500          ;                 -- "" --
9 L Z+100 R0 FMAX M129             ;M129 stänger av M128
10 M2
11 END PGM M128 manuellt MM
 

Pgm 17
Jag kör ner fräsen i ett hål, kör sedan bordet runt, och fräsen "följer med i hålet".

M128= verktygets XYZ är KVAR i samma position (om jag inte ändrar XYZ förstås), även om jag vrider A,B eller C i maskinen.

Typiskt bra om jag ska fräsa 5-axligt, se ovan på denna sida.

Valter den 23 mars 2010

Bilden visar att man kan stoppa (röd NC-stopp) mitt i block 8, vrida bordet C, och då följer fräsen med hålet.
Man kan även vrida B-huvudet, och fräsen står kvar med spetsen på samma plats i biten, men fräsen går av förstås i detta fall, så jag körde upp i Z lite först...

Milling a cylinder with A and X motion.

0 BEGIN PGM Skruv med A-axel MM
1 ;Fräser 20 varv kring en cylinderaxel. Valter Isander, Rönninge, Sweden, den 13 maj 2010
2 ;Graf ok 530 om A axel finnes
3 ;obs M128 används som vanligt /used as usual
4 ;
5 BLK FORM 0.1 Z X-100 Y-100 Z-100
6 BLK FORM 0.2 X+100 Y+100 Z+100
7 ;YZ nollan i A cyl axel, dock ej nödvandigtvis i A centrum.
   ;YZ zero point in part center axis (X), but NOT the same as the A's rotating axis
8 CYCL DEF 247 ORIGOS LAEGE ~
Q339=+1 ;UTGAANGSPUNKT-NUMMER (may be skipped)
9 TOOL CALL 6 Z S1000 ; ordinary tool, R9
10 CYCL DEF 7.0 NOLLPUNKT (may be skipped)
11 CYCL DEF 7.1 Z+0
12 CYCL DEF 7.2 Y+0
13 L Z+200 R0 FMAX
14 M128                     ;red text is the pgm core
15 L A+0 R0 FMAX
16 L X-100 Y+0 Z+110 R0 FMAX M3
17 L Z+100 R0 F2000
18 Q10 = 10 / 360 ;ix om IX10 per varv och 1 grad IA
(makes IX matching IA+1° exaktly)
19 Q1 = 90 ;vinkel YZ
20 LBL 2
21 Q1 = Q1 + 1 ;ny vinkel YZ
22 Q2 = 100 * SIN Q1 ;Z
23 Q3 = 100 * COS Q1 ;Y
24 L IA+1 IX+Q10 Y+Q3 Z+Q2 F2000
25 CALL LBL 2 REP7199
26 L Z+200 R0 FMAX M2
27 END PGM Skruv med A-axel MM

Graphic in editing mode, 3D

PGM 18

Milling a cylinder with A and X motion.

In this program I used M128 to show that one can put the part zero (YZ) NOT in the same position as the A-axis rotating axis point (YZ).

The solution is to generate a point that moves YZ around the cylinder (Q2 and Q3, simple triginometry for a  circle).

You may probably use polar motion CC Y..Z.. in stead of my formulas, but then you must sidestep in X in a separate block (because TNC cannot mix LP with third axis X --  but CP may work!....).

See this graphic live on YouTube!

Distributed on the 13'th of May 2010
Valter Isander, Rönninge, Sweden
 

General note on NC graphic:
TOOL IS ALWAYS MOVING!
PART IS ALWAYS STATIC!
ACCORDING TO MACHINE TOOL ISO RULES.

Consequence is that in TNC graphic 3D, the tool rotates around the part! (TEST MODE)

(the TNC machine graphics seems not showing this quite correct - softw 340494 05 SP5).

Machine with A-axis and M128
(or TCPM) set up.

NOTE!

If your machine does not have M128 or TCPM, for example an old machine - TNC355 and similar do the following:

1 Put the part zero YZ in A-axis!
2 Run the following program:

PGM 19 ----- without M128
BLK... no use
TOOL CALL 6  Z   S1000
L A0  FMAX M3
L X-100 Y0  Z110  R0 FMAX
L  Z100       F2000           ;touch the cylinder surface
LBL 2
L  IA+360  IX+20            ;one screw turn
CALL LBL  2  REP 20     ;total 21 turns, IX410 mm
L Z200  FMAX  M2

note: the feedrate F2000 will be correct only when the cylinder radius is about 57 mm, otherwise lower or higher than F2000 mm/min (tool feedrate in part material).

Här fräser jag tredje sidan med dubbelhuvudet AB,
men i programmet är B=15° (Q2) och C=-144° (Q32)

0 BEGIN PGM Pyramider-Multi MM
1 Q1 = 22           ;forskjutn. X normalt till Z-axeln snett
2 Q2 = 15            ;sidans lutning grader
3 Q3 = 5       ;Antal sidor paa pyramiden
4 ;
5 ;Med PLANE programmerar man verktygets vinklar i detaljens koord.system,~
inte maskinens vinklar, dvs programmet funkar i olika maskintyper, med~
olika axlar ABC
6 ;
7 ;Kinematic nr 0, B head C table
8 ;Kinematic nr 20, AB swivel table
9 ;Kinematic nr 25, BC swivel table 45-50 graders
10 ;
11 Q30 = Q3 - 1 ;Antal REP
12 Q31 = 360 / Q3 ;deln vinkel C
13 Q32 = 0 ;C reset
14 BLK FORM 0.1 Z X-55 Y-55 Z-20
15 BLK FORM 0.2 X+55 Y+55 Z+0
16 TOOL CALL 20 Z S1000 ;R26 pinne eller liknande
17 Q1 = Q108 + Q1 ;X snett. Detta block motsvarar RL kompensering, vilket~
ocksa kan anvandas
18 L Z+100 R0 FMAX M3
19 PLANE RESET MOVE DIST100 FMAX
20 ;
21 LBL 1
  22 PLANE SPATIAL SPA+0 SPB-Q2 SPC+Q32 TURN FMAX
  23 L Z+40 R0 FMAX M3
  24 L X+Q1 Y+80 R0 FMAX
  25 L Z-40 R0 F2000
  26 L Y-80                   ;KANT FRASES NU
  27 L Z+40
  28 Q32 = Q32 - Q31   ;C vinkel for nasta sida
29 CALL LBL 1 REPQ30
30 ;
31 PLANE RESET MOVE DIST100 FMAX
32 M2
33 END PGM Pyramider-Multi MM

PGM 19
MULTI-PYRAMIDER.h

Q1=Avståndet från sneda Z-axeln till kanterna på toppen
Q2=Sidornas lutning från vertikalen
Q3= antalet sidor i pyramiden

Alltså enkelt att köra fram en godtycklig "pyramid", t ex med 2, 3, 4, 5 eller 8 eller 19 sidor... ändra bara Q3 i block 3.

Detaljen kan spännas upp varsomhelst på rundbordet, eller på maskinbordet (om dubbel vinkelbart huvud). Maskinens vinkelaxlar kan heta "vadsomhelst" (dvs AB, AC, BC), eftersom TNC530 med PLANE-funktionen fixar till så att maskinens vinkelaxlar vrids rätt automatiskt.

XYZ nollpunkt ligger i mitten på toppen som vanligt. XY-nollan måste inte sammanfalla med maskinbordets rotationsaxel - PLANE i TNC sköter om allt...

ALLTSÅ IGEN!!!!!
I PLANE anger man verktygets (detaljytans) vinkel i XYZ-systemet, inte maskinens vinkelaxlars värden. Det är det som är det fina med PLANE!

Man kan köra med MOVE eller TURN i PLANE. Men om du kör med STAY måste du själv vrida maskinens vinkelaxlar med t ex
L AQ120 BQ121 (se maskinens A...B... i bilden ovan till vänster).

Ha det skönt i sommar!
Valter Isander, Rönninge, den 29 juni 2010

Q3=3

Q3=4

Q3=8

Q3 är antalet sidor på detaljen. Det kan vara från 2 st eller mer, tja 1 går väl också...

På menyn idag:

PLANE AXIAL!

0 BEGIN PGM Borra med PLANE AXIAL MM
1 ;Borra snett i mitten av bortre kanten på biten
2 ;Halet pekar 60 grd nedat, dvs rymdvinkel A-30, 15 grd vridet sett uppifran, dvs rymdvinkel C-15
3 ;Valter Isander den 20 sept 2010
4 ;Kinematic 45-graders huvud, A-B-axlar
5 BLK FORM 0.1 Z X+0 Y+0 Z-50
6 BLK FORM 0.2 X+100 Y+100 Z+0
7 TOOL CALL 1 Z S1000
8 L X+0 Y+0 Z+100 R0 FMAX M3
9 CYCL DEF 7.0 NOLLPUNKT
10 CYCL DEF 7.1 X+50
11 CYCL DEF 7.2 Y+100
12 CYCL DEF 7.3 Z+0

       ;Följande  gråa block använde jag bara för att TNC:n ska beräkna ;maskinens fysiska AB-axlar - det utförs ju av PLANE SPATIAL i block 13, där jag ;anger verktygets vinkel i XYZ-systemet, inte maskinens fysiska AB-;vinklar. Sedan låter jag PLANE AXIAL använda de vinklarna (Q1, Q2).

;I stället hade jag kunnat titta i maskinens "pärm" (det gamla ;sättet alltså) för att se vilka vinklar maskinens huvud vill ha ;för att verktyget ska stå i önskad rymdvinkel, i detta fall A-;30° och C-15°, vilket resulterar i maskinvinklar A+88,047 och ;B-45.311 (detsamma som B+314,689 se bilden till höger)

13 PLANE SPATIAL SPA-30 SPB+0 SPC-15 STAY
14 ;spar beraeknade vinklarna AB foer denna maskin i Q1, Q2, de beraeknas ju~
av PLANE!
15 Q1 = Q120 ;Maskin axel A..88,047
16 Q2 = Q121 ;Maskin axel B..-45.311
17 Q3 = Q122 ;Maskin axel C, finns ej i denna maskin....
18 PLANE RESET STAY ;staeng av PLANE, vi ska ju leka med PLANE AXIAL, inte
PLANE SPATIAL...

19 ;
20 ;Nu provar vi PLANE AXIAL med de av PLANE beraeknade vaerdena!
21 PLANE AXIAL A+Q1 B+Q2 MOVE DIST 0 F1000
22 L X+0 Y+0 Z+50 R0 FMAX M3 ;Mitt foer haalet
23 CYCL DEF 200 BORRNING ~
Q200=+2 ;SAEKERHETSAVSTAAND ~
Q201=-60 ;DJUP ~
Q206=+200 ;MATNING DJUP ~
Q202=+10 ;SKAERDJUP ~
Q210=+0 ;VAENTETID UPPE ~
Q203=+0 ;KOORD. OEVERYTA ~
Q204=+2 ;2. SAEKERHETSAVST. ~
Q211=+0 ;VAENTETID NERE
24 CYCL CALL M3
25 L Z+100 R0 FMAX
26 PLANE AXIAL A+0 B+0 MOVE DIST0 F1000 COORD ROT
27 CYCL DEF 7.0 NOLLPUNKT
28 CYCL DEF 7.1 X+0
29 CYCL DEF 7.2 Y+0
30 CYCL DEF 7.3 Z+0
31 L X+0 Y+0 Z+100 R0 FMAX M5
32 M2
33 END PGM Borra med PLANE AXIAL MM
 

Vad är PLANE AXIAL?!

Varför finns numera kommandot PLANE AXIAL i TNC530?
Jo i PLANE AXIAL kan du mata in maskinens vinklar!

Så här är det alltså:
1
först kom CYCL 19, ojoj, då måste användaren bestämma sig för om vinklarna var RYMDVINKLAR (det som "står på ritningen", eller FYSISKA VINKLAR ("det som maskinens axlar ska köras till för att det ska motsvara ritningens vinklar"). Man kunde ställa om mellan dessa principer med en maskinparameter MP7500. Men hur kul är det att greja med maskinparametrar.☻○°▬*!? Nä.

2
Sedan kom PLANE (alltid rymdvinklar), OK! Men det fanns ingen PLANE där man kunde mata in maskinens vinklar (som en del vill göra, de kan ju stå på en ritning eller i gamla program!)

3
Då kom tillägget PLANE AXIAL.
Nu kan man välja allt med PLANE...:
Gör så här:
- SPATIAL om man vet rymdvinklar
- AXIAL om man vet maskinens fysiska vinklar

I programmet till vänster borrar jag ett hål snett. Det kräver att den aktuella maskinens huvud (se bilden till höger) vrids i två axlar A, B. Dessa vinklar är ju inte desamma som står på ritningen (som är 30 och 15°).

PLANE SPATIAL (och CYCL 19 med rymdvinkel inställt) räknar ut maskinens vinklar (Q120-Q122) - om man inte redan vet dessa vinklar... alltså kunde jag, som inte visste de maskinvinklarna, köra en PLANE SPATIAL (utan huvudvridning dvs STAY), så vips fick jag Q120-... Sedan körde jag en PLANE AXIAL med de vinklarna Q120... och fick rätt hål borrat.

Alltså:
Om du vet maskinvinklarna, men inte verktygets rymdvinklar, har du nytta av PLANE AXIAL. Ange axlar ABC som din maskin har, NOENT på de den inte har.

Många maskiner kan inte vrida vinklarna steglöst. Då kan du förstås inte räkna med att MOVE eller TURN funkar. Men STAY funkar kanske... dvs bara koordinatsystemets XYZ-axlar vrids matematiskt, maskinen är still - DEN vridningen får du sköta på annat sätt, kanske en CYCLE från din maskintillverkare!

Hälsar
Valter den 20 september 2010

Maskinen har ett 45-gradershuvud, två vridbara axlar alltså.

Med ett sådant steglöst huvud kan du nå "alla" vinklar med verktyget.

Många maskiner har dock 1° eller 2,5° steg. Då måste man jämka lite, fråga kunden om han accepterar att vinkeln blir t ex 30,07° i st f 30,000°....

Kolla när det här programmet körs på YouTube

0 BEGIN PGM ROR21 MM
1 ; PSURF 2011/03/03 15:31:40
2 ;Copyright 2011 Valter Isander
3 TOOL CALL 20 Z S1500      ;R10 FULL R
4 CYCL DEF 10.0 VRIDNING
5 CYCL DEF 10.1 ROT+0
6 CYCL DEF 7.0 NOLLPUNKT
7 CYCL DEF 7.1 X+0
8 CYCL DEF 7.2 Y+0
9 CYCL DEF 7.3 Z+0
10 ;KROKIGT ROER: ROERRADIE= 50
11 ; KROKRADIE= 100
12 ; STARTVINKEL XY= 0
13 ; SLUTVINKEL XY= 180
14 ; STARTVINKEL ROERYTA= 0
15 ; SLUTVINKEL ROERYTA= 180
16 ; KLAETTRINGSVINKEL= 2
17 ; FRAESRIKTNING DR= 1
18 ; VRIDNINGSVINKEL=0
19 BLK FORM 0.1 Z X-155 Y+0 Z+0
20 BLK FORM 0.2 X+155 Y+155 Z+70
21 CYCL DEF 10.0 VRIDNING
22 CYCL DEF 10.1 ROT+0
23 L Z+300 R0 F9999 M3
24 L M3

25 FN 0: Q56 =-2      ;START KLÄTTR.VINKEL (JUSTERAD)
26 LBL 56
27 L Z+300 R0 F9999
28 FN 1: Q56 =+Q56 + +2               ;OEKA KLÄTTR.VINKELN
29 FN 7: Q57 = COS +Q56
30 FN 3: Q57 =+Q57 * +60
31 FN 2: Q57 =+100 - +Q57
32 CC X+0 Y+0
33 LP PR+Q57 PA+0 R0 F9999               ;FRAM ÖVER NY STARTPKT
34 FN 6: Q58 = SIN +Q56
35 FN 3: Q58 =+Q58 * +60
36 FN 1: Q59 =+Q58 + +30
37 L Z+Q59 R0 F9999
38 L Z+Q58 R0 F80 ;NED NYTT Z
39 CP PA+180 DR+ R0 F120
40 FN 12: IF +Q56 LT +180 GOTO LBL 56

41 L Z+300 F9999
42 END PGM ROR21 MM
 

Detta är ett exempel på hur man stegar fram en krökt yta med successiva stegande skär. Det egentliga bearbetningsskäret är block 39 CP ... som kör en cirkelbåge 180° horisontellt.

Fräsradiekompensering används som vanligt inte i sådana här ytprogram, du måste själv lägga in beroendet av fräsens radie (stammen och änden, i detta fall samma R10, en fullradiefräs).

Det finns enklare sätt att lösa just detta fall, helt utan SIN, COS, men som vanligt... det finns många sätt att sätta ner ett spett.

Programmet bör funka även i så gamla TNC som TNC150, som ju har Q-funktioner.

Valter Isander

Rönninge den 3 mars 2011

Jämför med nästa PGM 22, som gör samma sak. PGM 21 är dock mer generellt eftersom man kan starta och klättra i godtycklig vinkel.

Ja så här blev biten i grafiken.
I verktygstabellen bör du sätta R10 och R2=10, då ser du verkligt verktyg och detalj i grafiken. Men i maskinen blir biten rätt vad du än sätter i verktygstabellen...

Verktygslängden mäter jag till spetsen som vanligt.

Detta är ett exempel på hur man stegar fram en krökt yta med successiva stegande skär. De egentliga bearbetningsskären är block 22 och 26 CP ... som kör en cirkelbåge 180° horisontellt.

Fräsradiekompensering används som vanligt inte i sådana här ytprogram, du måste själv lägga in beroendet av fräsens radie (stammen och änden, i detta fall samma R10, en fullradiefräs).

Vid TOOL CALL laddas Q108 med R10, som jag sedan använder i de gröna orden, eftersom jag vill programmera verktygets SPETS, inte verktygskulans centrum...

Programmet använder alltså inga Q-funktioner (Q108 kan man ersätta med 10).

Programmet bör funka även i så gamla TNC som TNC150, som ju har Q-funktioner, dock har TNC150 inte Q108, det kom med TNC155Q.

(c) Valter Isander

Rönninge den 3 mars 2011

Grafiken visar detta.
Endast block 28 L Z+100 kvarstår att exekvera.

Programmet använder CC X...Z... (eller CC Y...Z... om du vill klättra i ett YZ-plan), vilket kräver att du klättrar i ett 90°-gradersläge, dvs man kan inte klättra 3-axligt XYZ med CC... CP... (jo i allra senaste TNC530 tror jag).

Konens topp R100. Vinkel 20°. Djup 90 (längs 20°-sidan).

Rörlig grafik på Youtube: Zl2iw02LOyI

Tre vyer


T ex 5-axlig maskin med XYZAC.
Även andra maskiner med fem kontinuerliga axlar kan fungera med detta program.

Valter Isander maj 2014
valter.isander@telia.com

(Fräsning av sidor med vinkel, Heidenhain TNC320, 530, 640, 426 m fl)

Want to try this “Cycle”?
It will easy cut any contour with angled side/sides.
Use my subprogram Valter25.h and make a part program (see test program) calling Valter25.h.
Tool data (R and R2, any tool) in Tool Table as usual.
Easy to use! Only one Q (angle).

How to install:
1 Use a TNC320, 530, 640 (Q function SYSREAD).
2 Copy text Valter25.h and the test pgm. Save in two files on PC, text files, try Wordpad by paste+save to .H file.
3 Transfer the two files from PC to your TNC, best in same folder.
4 Use a tool in Tool table (se Tool call in test pgm), R and corner R2 as you wish.
5 Start and run graphics, see how it works
6 Try other tool R/R2, angle Q20, contour in LBL 1-LBL 0 etc.
7 Use in production
8 Don’t edit Valter25.h … 😁

Good luck!
 

See also
https://www.facebook.com/groups/TNC.programmering.med.Valter/permalink/6796818460391192/

Other examples:

A cone

Combined with standard PLANE in TNC

Video for TestValter25
https://1drv.ms/v/s!Ahj2aLMfWRNFh88PqXdVEO5XSArwQg
 

A common part, milled by Valter25.h

220-06-21 by Valter Isander, Sweden

Make your own part program:

1 TOOL in TOOL TABLE! R and R2 may be set.
2 TOOL CALL ...
3 Q20=... the side angle to be milled. 90 is vertical. 0 is not possible.
4 CYCL 14... the contour LBL
5 CYCL 25 as in the TNC handbook
6 M3
7 CALL PGM Valter25.h  This is the "cycl call" to the subprogram
8 M2
9 LBL 1
.... Your contour as in TNC handbook
.. LBL 0
End PGM

Here is a test program
TestValter25
 

0 BEGIN PGM TestValter25A MM
1 BLK FORM 0.1 Z X-20 Y-20 Z-31
2 BLK FORM 0.2 X+120 Y+120 Z+0
3 TOOL CALL 1 Z S1000 ;Full R20
4 Q20 = 60 ;Side angle. *90 is vertical*
5 CYCL DEF 14.0 KONTUR
6 CYCL DEF 14.1 KONTURLABEL1
7 CYCL DEF 25 KONTURLINJE ~
Q1=-40 ;FRAES DJUP ~
Q3=+0 ;TILLAEGG SIDA ~
Q5=+0 ;KOORD. OEVERYTA ~
Q7=+30 ;SAEKERHETSHOEJD ~
Q10=+8 ;SKAERDJUP ~
Q11=+150 ;MATNING DJUP ~
Q12=+800 ;MATNING FRAESNING ~
Q15=+1 ;FRAESSMETOD ~
Q18=+0 ;FOERBEARB.VERKTYG ~
Q446=+0.01 ;RESTMATERIAL ~
Q447=+10 ;ANSLUTNINGSAVSTAAND ~
Q448=+2 ;BANFOERLAENGNING
8 M3
9 CALL PGM Valter25.h
10 M2
11 ;
12 ; your contour
13 LBL 1
14 L X+0 Y+50 RL
15 L Y+100
16 L X+100
17 L Y+80
18 CR Y+20 R-32 DR+
19 L Y+0
20 L X+0
21 L Y+50
22 LBL 0
23 END PGM TestValter25 MM
 

0 BEGIN PGM Valter25 MM
1 ;Valter Isander, Stockholm 18 February 2020
2 ;This program executes the milling of a contour with sides at an angel~
0,001 to 90 degrees.
3 ;Angele is defined as Q20=... in the user program. Vertical side is Q20=90.~
This program is called by the user as CALL PGM Valter25.h
4 ;The tool may be cylindric R=..., R2=0, or with a corner radius R2=...~
These values must be set in TOOL TABLE
5 ;
6 ;Check input for acceptable values
7 FN 12: IF +Q20 LT +0.1 GOTO LBL 99 ;Angle too small, zero not okay
8 FN 11: IF +Q20 GT +90 GOTO LBL 99 ;Angle too large, max 90
9 ;
10 Q33 = Q1 ;Copy input DEPTH
11 Q34 = Q10 ;Copy input CUT DEPTH
12 FN 18: SYSREAD Q22 = ID50 NR3 ;TOOL R2. R is in Q108 after TOOL CALL
13 ;
14 Q31 = ABS ( INT ( ABS ( Q33 / Q34 ) + 0.9 ) ) ;Number of slices, rounded~
up, if 10 proc more;
15 Q40 = ABS ( Q1 / Q31 ) ;One slice depth mm
16 ;
17 Q42 = 0 ;Number of cuts executed so far, i e counter. Note-top of part is~
cut, ie touched
18 Q1 = - ABS ( Q40 ) ;start first cut, then add Q40
19 Q10 = Q1 ;adjusted CUT DEPTH at start, then add Q40
20 ;
21 ;Now calculate the corresponding DR value Q43 to get correct side angle. DR~
always positive, meaning angle max 90 degr
22 Q43 = ABS ( Q33 * TAN ( 90 - Q20 ) / Q31 ) ;DR increment, always positive,~
as if sharp tool
23 Q44 = 0 ;DR init
24 ;
25 Q56 = Q22 - Q22 * SIN Q20 ;adjust DR due to corner Radius R22
26 Q57 = - ( Q22 - Q22 * COS Q20 ) ;adjust DL due to corner Radius Q22
27 ;
28 LBL 1 ;now loop ----------
29 Q44 = Q44 + Q43 ;Next DR for next cut as for sharp tool
30 ;
31 ;adjust for corner radius R2 in tool table, meaning Q22
32 Q52 = Q44 - Q56 ;resulting DR to use in next cut, meaning Q20 and the R2~
infuencing
33 TOOL CALL DL+Q57 DR+Q52 ;Next cut
34 M99
35 Q1 = Q1 - ABS Q40 ;DEPTH mow this cut
36 Q10 = Q1 ;all in one slice at M99
37 Q42 = Q42 + 1 ;Cut counter
38 FN 12: IF +Q42 LT +Q31 GOTO LBL 1 ;More cutting?
39 ;-------------
40 ;
41 ;Finished contour all cuts, now reset input Q1 and Q10 for correct use~
later
42 Q1 = Q33
43 Q10 = Q34
44 FN 9: IF +0 EQU +0 GOTO LBL 100
45 LBL 99 ;Error input
46 FN 15: PRINT Q20
47 FN 14: ERROR= 99 ;Not allowed is.. Q20=0, Q20>90
48 LBL 100 ;OK finished
49 END PGM Valter25 MM